Amiga Plus Leser 19/Amiga Plus Leser CD 19.iso/Tools/DruckerTreiber/PrintManager39/Install

Text File | 1999-10-13 | 5KB | 228 lines

; $VER: Installer script for PrintManager 1.11 (13.10.99) © 1997-1999 by Stephan Rupprecht

;--- localize strings ----
(if (= @language "deutsch")
(
    (set #wrongver "PrintManager benötigt mindestens AmigaOS3.0.\nInstallation kann nicht durchgeführt werden.")
    (set #askdir_prompt "Bitte wählen Sie das Zielverzeichnis für den PrintManager")
    (set #install_doc "Bitte wählen Sie das Verzeichnis für die Anleitung")
    (set #no_doc "Anleitung nicht installieren")
    (set #apply_fparpatch "Die fastpar.device wird nun auf den aktuellen Stand gebracht.\n")
    (set #apply_fparpatch_err "Update der fastpar.device kann nicht durchgeführt werden")
    (set #gtdrag_prompt "Soll die gtdrag.library installiert werden?")
    (set #gtdrag_help "Die gtdrag.library von Axel Dörfler ermöglicht es Ihnen die Auftragsliste mittels "Ziehen und Fallenlassen" (DragNDrop) zu verändern.")
)
(
    (if (= @language "español")
    (
        (set #wrongver "PrintManager requiere al menos S.O. 3.0\nInstalación abortada.")
        (set #askdir_prompt "Por favor, elija el cajón donde desea que PrintManager sea instalado.")
        (set #install_doc "Por favor, elija el cajón donde desea instalar la documentación.")
        (set #no_doc "No instalar documentación")
        (set #apply_fparpatch "Ahora se va actualizar `fastpar.device' (37.6).")
        (set #apply_fparpatch_err "Intento fallido de actualizar `fastpar.device'")
        (set #gtdrag_prompt "¿Desea instalar la biblioteca `gtdrag.library'?")
        (set #gtdrag_help "La biblioteca `gtdrag.library' de Axel Dörfler le permite modificar la lista de tareas simplemente arrastrando y soltando las entradas.")
    )
    (
        (set #wrongver "PrintManager requires at least AmigaOS3.0\nInstallation aborted.")
        (set #askdir_prompt "Please select the drawer where PrintManger should be installed")
        (set #install_doc "Please select the drawer for the documentation")
        (set #no_doc "Don't install doc")
        (set #apply_fparpatch "Now going to update fastpar.device (37.6).")
        (set #apply_fparpatch_err "Failed to update fastpar.device")
        (set #gtdrag_prompt "Do you wish to install gtdrag.library?")
        (set #gtdrag_help "gtdrag.library by Axel Dörfler allows you to change the joblist by Drag'N'Drop.")
    )
    )
)
)

;--- check os version ---
(set #vernum (getversion "exec.library" (resident)))
(set #vernum (/ #vernum 65536))

(if(< #vernum 39)
    (abort #wrongver)
)

;--- copy main program ---
(set @default-dest
    (askdir
        (prompt #askdir_prompt)
        (help @askdir-help)
        (default "SYS:WBStartup")
    )
)

(if (patmatch "68000|68010" (database "cpu"))
(
    (abort "Sorry, 68000/010 CPUs aren't supported!")
)
;--- 020+ cpu installed ---
(
    (copyfiles
        (help @copyfiles-help)
        (source "PrintManager")
        (dest @default-dest)
    )
)
)

;--- copy .info file if neccessary ---
(set #info_path (tackon @default-dest "PrintManager.info") )

(if (not (exists #info_path) )
    (copyfiles
        (help @copyfiles-help)
        (source "PrintManager.info")
        (dest @default-dest)
    )
)

;--- delete spool.device ---
(if (exists "DEVS:spool.device")
    (delete "DEVS:spool.device"
    )
)

;--- copy catalog ---
(if (NOT (= @language "english"))
(
    (set #src_name
        (tackon "Catalogs/" @language)
    )

    (set #dst_name
        (tackon "LOCALE:" #src_name)
    )

    (set #src_name
        (tackon #src_name "printmanager.catalog")
    )

    (if (exists #src_name (noreq))
    (
        (copyfiles
            (help @copyfiles-help)
            (source #src_name)
            (dest #dst_name)
        )
    )
        (message "Sorry, there is no " @language " catalog available at the moment!")
    )
)
)

;--- copy doc ---
(set #progdir
    (cat "PROGDIR:" " (aka " @default-dest ")" )
)

(set #helpdir
    (tackon "HELP:" @language)
)

(set #choice
    (askchoice
        (prompt #install_doc)
        (help @askchoice-help)
        (choices #helpdir #progdir #no_doc)
        (default 0)
    )
)

(if (< #choice 2)
(
    (if (exists "HELP:PrintManager.guide")
    (
        (Delete "HELP:PrintManager.guide")
    )
    )

    (if (= #choice 1)
    (
        (set #dst_name @default-dest)
    )
        (set #dst_name #helpdir)
    )

    (set #src_name
        (cat "docs®forms/" @language "/PrintManager.guide")
    )

    (if (NOT (exists #src_name) )
    (
        (set #src_name "docs/english/PrintManager.guide")
    )
    )

    (copyfiles
        (help  @copyfiles-help)
        (source #src_name)
        (dest #dst_name)
    )

    (set #src_name
        (cat #src_name ".info")
    )

    (copyfiles
        (help  @copyfiles-help)
        (source #src_name)
        (dest #dst_name)
    )
)
)

(copylib
    (source "libs/gtdrag.library")
    (dest "LIBS:")
    (prompt #gtdrag_prompt)
    (help #gtdrag_help)
    (confirm)
)

;--- update fastpar.device ---
;--- revision check doesn't work due a bug in 'getversion' ---
;(set #vernum (getversion "devs:fastpar.device"))
;(set #ver (/ #vernum 65536))
;(set #rev (- #vernum (* #ver 65536) ) )

;(if(< #rev 6)
;(

(if(exists "DEVS:fastpar.device")
(
    (set #err
        (run "C:Version DEVS:fastpar.device REVISION 6")
    )

    (if (<> 0 #err)
    (
        (message #apply_fparpatch)

        (set #err
            (run "gpatch DEVS:fastpar.device fastpar.ptch t:fastpar.device")
        )

        (if (> #err 0)
        (
            (message #apply_fparpatch_err)
        )
        (
            (copyfiles
                (help @copyfiles-help)
                (source "t:fastpar.device")
                (dest "devs:")
            )

            (delete "t:fastpar.device")
        )
        )
    )
    )
)
)
;--- eof ---